Android Jacoco多模块单元测试覆盖率

Android 默认配置了单元测试和集成测试的任务，Run test on build variant：

#本地测试：testXxxUnitTest
./gradlew biz_a:testDebugUnitTest
 
#设备测试：connectedXxxAndroidTest
./gradlew biz_a:connectedDebugAndroidTest

本文只统计单元测试的覆盖率，只依赖testXxxUnitTest任务。

配置

    def jacocoFileFilter  = [
            //Android stuff
            '**/R.class',
            '**/BR.class',
            '**/R$*.class',
            '**/BR$*.class',
            '**/BuildConfig.*',
            'android/**/*.*',
            '**/immersionbar/*.*',
            '**/statusbar/*.*',
            '**/widget/*.*',
            '**/log/impl/*.*',
            '**/log/upload/*.*',
            '**/TSpanView.java',
            'android/**/*.*',
            //Data Binding
            '**/*databinding',
            '**/*binders',
            '**/*layouts',
            '**/Manifest*.*',
            //Test mocks
            '**/*Mock.*',
            //'**/*Test*.*',
            //Data classes (without any logic)
            "**/services/**/model/**",
            '**/*$$ViewBinder*.*',
            '**/inject/*',
            '**/*$InjectAdapter.*',
            '**/Dagger*.*',
            '**/*$ModuleAdapter.class',
            '**/*$ViewInjector*.class'
    ]

app level

apply plugin: 'jacoco'
 
// build type 配置
jacoco {
    toolVersion "0.8.5"
}
android {
    testBuildType "debug"
    buildTypes {
        // This is a new build type specifically for automation test
        // run like `test Id Internal AutomationTest UnitTest` for unit test
        debug {
            testCoverageEnabled = true // !!!
        }
    }
 
    testOptions {
        unitTests.returnDefaultValues = true
        animationsDisabled true
    }
}
 
 
// 模块配置
def jacocoModules = [
        'app', 'biz_a', 'biz_b', 'biz_c', 'biz_d',
]
def jacocoFileFilter  = [...]
//debug: To support Java coverage on Unit tests
def jacocoClassDirectories = files(jacocoModules.collect {
    'app' == it ?
            fileTree(dir: "${buildDir}/intermediates/javac/debug/classes", excludes: jacocoFileFilter) :
            fileTree(dir: "../${it}/build/intermediates/javac/debug/classes", excludes: jacocoFileFilter)
})
def jacocoSourceDirectories = files(jacocoModules.collect {
    'app' == it ?
            "${project.projectDir}/src/main/java" :
            "../${it}/src/main/java"
})
def jacocoExecList = files(
        fileTree(dir: "${buildDir}/outputs/code-coverage/debugAndroidTest/connected/", includes: ["*.ec"]),
        jacocoModules.collect {
            'app' == it ?
                    "${buildDir}/jacoco/testDebugUnitTest.exec" : // app
                    "../${it}/build/jacoco/testDebugUnitTest.exec"
        }
)
 
// :app Unit Test Coverage
task createUnitTestReport(
        type: JacocoReport,
        dependsOn: [':app:testDebugUnitTest']
) {
    group = "JacocoReport"
    reports {
        xml.enabled = true
        html.enabled = true
    }
 
    getSourceDirectories().setFrom(files(
            "${project.projectDir}/src/main/java" , // mainSrc
            "${project.projectDir}/src/debug/java", // debugSrc
    ))
    getClassDirectories().setFrom(files(
            fileTree(dir: "${buildDir}/intermediates/javac/debug/classes", excludes: jacocoFileFilter), // java debugTree
//            fileTree(dir: "${buildDir}/tmp/kotlin-classes/automationTest", excludes: fileFilter), // kotlinDebugTree
    ))
    getExecutionData().setFrom(files(
            "${buildDir}/jacoco/testDebugUnitTest.exec",
            fileTree(dir: "${buildDir}/outputs/code-coverage/debugAndroidTest/connected/", includes: ["*.ec"]) // appAndroidTests
    ))
}
 
 
//Global Test Coverage，整合app和所有子模块的单元测试报告生成一个总的覆盖率报告
task createGlobalTestReport(
        type: JacocoReport,
        dependsOn: jacocoModules.collect {
            ":${it}:createUnitTestReport"
        }
) {
    group = "JacocoReport"
    reports {
        xml.enabled = true
        html.enabled = true
    }
 
    getSourceDirectories().setFrom jacocoSourceDirectories
    getClassDirectories().setFrom jacocoClassDirectories
    getExecutionData().setFrom jacocoExecList
}

module level

apply plugin: 'jacoco'
 
// TEST COVERAGE
jacoco {
    toolVersion "0.8.5"
}
android {
    // This is a new build type specifically for test
    testBuildType "debug"
    buildTypes {
        debug {
            testCoverageEnabled = true // !!!
        }
    }
 
    testOptions {
        unitTests.returnDefaultValues = true
        animationsDisabled true
    }
}
 
// module level Unit Test Coverage
task createUnitTestReport(type: JacocoReport, dependsOn: ['testDebugUnitTest']) {
    reports {
        html.enabled = true
    }
    def jacocoFileFilter  = [...]
    getSourceDirectories().setFrom(files(
            "${project.projectDir}/src/main/java", // mainSrc
            "${project.projectDir}/src/debug/java", // debugSrc
    ))
    getClassDirectories().setFrom(files(
            fileTree(dir: "${buildDir}/intermediates/javac/debug/classes", excludes: jacocoFileFilter), // java debugTree
//            fileTree(dir: "${buildDir}/tmp/kotlin-classes/automationTest", excludes: fileFilter), // kotlinDebugTree
    ))
    getExecutionData().setFrom(files(
            "${buildDir}/jacoco/testDebugUnitTest.exec",
    ))
}

这篇好文章是转载于：学新通技术网